Excel HVIS() – på godt og vondt

| | |
AvKetil Øyesvold Melhus Publisert Redigert

Excel HVIS()

Jeg får mange eksempler fra dere der ute med komplekse HVIS-formler. Mange av disse kan forenkles ved å bruke Finn.Rad eller kombinasjonen av Indeks og Sammenligne.

I bunnen av denne artikkelen finner du «Grunnleggende om Excel HVIS», hvis du har behov for det

Les også: Fra HVIS() til HVIS.SETT()

I dette eksemplet ser vi på hvordan vi automatisk kan sette karakterer ut fra elevens resultatoppnåelse, løst med HVIS – og mer hensiktsmessig med Finn.Rad samt Indeks og Sammenligne.

Les også: Aldri mer FINN.RAD()

(Artikkelen fortsetter under videoruten. )
YouTube player

De forskjellige formlene i eksemplet.

excel hvis
  • I C2 står resultatgraden eleven har oppnådd, f.eks 90%
  • I D2 ønsker vi å vise karakteren A-F ut fra resultatgraden.
  • I E2 ønsker vi å vise karakterens betegnelse

1) Karakter: Løst med HVIS, blir formelen slik:

=HVIS(C2>=90%;"A";HVIS(C2>=80%;"B";HVIS(C2>=50%;"C"; HVIS(C2>=30%;"D";HVIS(C2>=20%;"E";"F")))))

2) Karakter: Løst med Indeks og Sammenligne, blir formelen slik:

=INDEKS(Karakterskala!A:A;SAMMENLIGNE(C2; Karakterskala!B:B;1))

Ulempen med formel 1), er både at den er lang og dessuten inneholder alle reglene for karaktergivingen. Endres kravet for en A, må du inn i formelen og endre.

Formel 2) kan rent logisk være tyngre å sette seg inn i, men den har en stor fordel. Den henter informasjonen fra tabellen som inneholder reglene for karaktergivingen, og vil tilpasse seg endringer i tabellen. Siden vi leter etter en verdi som skal være mindre eller lik prosentsatsen i C2, velger jeg å bruke Sammenligne fremfor Finn.Rad, siden jeg har litt varierende erfaring med Tilnærmet verdi når jeg bruker Finn.Rad

3) Betegnelse: Løst med HVIS

I E2 står betegnelsen på karakteren som er gitt, f.eks «Fremragende»

Løst med HVIS, kan vi skrive denne formelen:

=HVIS(D2="A";"Fremragende";HVIS(D2="B";"Meget god";HVIS(D2="C";"God";HVIS(D2="D";"Nokså god";HVIS(D2="E";"Tilstrekkelig";"Ikke Bestått")))))

Igjen en kronglete formel, som vi kan erstatte med enten Indeks og Sammenligne, eller enda enklere med Finn.Rad.

4) Betegnelse: Løst med Finn.Rad

=FINN.RAD(D2;Karakterskala!A:C;3;USANN)

Ta en kikk på videoen hvis du vil ha en gjennomgang av formlene.

Det er absolutt mulig å løse mange oppgaver med HVIS, men når alternativene blir mange, finnes det svært effektive funksjoner du heller bør ta en kikk på.

Link til regnearket finner du nederst i artikkelen

Grunnleggende om Excel HVIS

excel hvis

I celle A2 vil jeg at det skal stå at A eller B er størst avhengig av verdiene i A1 og B1

excel hvis

Jeg prøver meg med denne formelen:

=HVIS(A1>B1;"A er størst";"B er størst")

A1>B1 er det vi skal teste om er sant.

«A er størst»

Hvis påstanden A1>B1 er sann, vil formelen utføre det som står etter første semikolon, i dette tilfellet teksten «A er størst».

«B er størst»

Hvis påstanden A1>B1 ikke er sann, vil det som står etter andre semikolon bli resultatet av formelen.

Hvis du tester formelen, ser du kjapt at det ikke er to muligheter, men tre. Hvis du setter A1 og B1 like, blir resultatet «B er størst».

Siden en HVIS-setning bare har to alternativer, må vi bruke to HVIS’er for å løse dette:

=HVIS(A1>B1;"A er størst";HVIS(B1>A1;"B er størst";"A og B er like"))
excel hvis

På denne måten får vi testet alle tre mulighetene:

excel hvis

Last ned regnearket her:  HVIS.xlsx (380 downloads )

Similar Posts