Betinget formatering – «Datapapir look» på skjermen

Vi kan bruke betinget formatering for å utheve annenhver rad i en liste uten å definere området som en tabell. Lesbarheten blir vesentlig bedre, litt som gammeldags «datapapir look» eller pyjamas-papir som det også ble kalt. I eksemplet bruker vi også funksjonene UNIK(), FILTRER() og SORTER()

Hvis du vil få rett til Betinget formatering og hoppe over alle de deilige formlene i Excelboka, kan du klikke her.

Fanene i eksemplet

Excelboka består av to faner, ‘Data’ hvor datagrunnlaget ligger og ‘ExcelGuru’ hvor vi viser utvalg fra Data-fanen.

Fylker

Hensikten med eksemplet er å vise oversikter over kommuner i hvert enkelt fylke, så vi trenger å lage en oversikt over alle fylkene i Data-fanen. Denne listen ligger i celle G2 i Data-fanen:

Formelen som trekker ut fylkene fra listen, ser slik ut:

=SORTER(UNIK(FILTRER(B2:B1000;B2:B1000<>0)))

Vi kunne i prinsippet klart oss med denne formelen:

=UNIK(B2:B1000)

Resultatet her blir ikke like gøy, fordi listen er usortert, og vi får med en null til slutt i listen, siden listen har 428 rader, og formelen inkluderer 999 rader fra 2 til 1000. Tomme celler har verdien 0 i Excel, altså får vi en null til slutt i listen. Dette unngår vi med å legge til FILTRER() :

=UNIK(FILTRER(B2:B1000;B2:B1000<>0))

Denne filtreringen ekskluderer alle celler som har null som verdi.

ExcelGuru-fanen

Ok, over til ExcelGuru-fanen og celle A2, hvor vi velger fylke. Her kan vi bruke datavalidering i cella for å få en nedtrekksliste som inneholder alle fylkene.

Datavalidering

Listen i A2 lager vi med Datavalidering som ligger under Data->Dataverktøy i menyen. Vi tillater Liste og under Kilde setter vi

=Data!$G$2#

Hesjetegnet (#) setter vi inn for å fortelle Excel at vi ikke bare er ute etter verdien i G2, men hele listen som starter i G2. Dette kan vi gjøre med alle lister som er resultatet av en matrisefunksjon.

Kommunelisten

I C2 skal vi vise alle radene fra Data-fanen som er i fylket som vises i A2.

I C2 setter vi inn formelen

=SORTER(FILTRER(Data!A2:D1000;Data!B2:B1000=A2);4)

Hvis vi bryter ned formelen litt

FILTRER(Data!A2:D1000;Data!B2:B1000=A2)

Data!A2:D1000 er området vi vil vise i uttrekket

FILTRER(Data!A2:D1000;Data!B2:B1000=A2)

Data!B2:B1000=A2 er betingelsen vi setter for at en rad skal bli med, altså at cellene i B-kolonnen skal være lik fylkenavnet i A2 for at de skal være med i uttrekket.

=SORTER(FILTRER(Data!A2:D1000;Data!B2:B1000=A2);4)

Så hekter vi på SORTER og sier at listen skal sorteres etter kolonne 4, D-kolonnen, som er kommunenavnet.

Betinget formatering

Ja, så er vi endelig på den betingede formateringen av annenhver rad, da.

Vi markerer først området fra C2 til F100 (så langt ned vi gidder). Betinget formatering finner du under HJEM og Betinget formatering. Her velger vi å sette inn en formel:

Det er to betingelser som gjelder. Det ene er at raden ikke skal være tom. Det andre er at radnummeret ikke skal være delelig med to. Hvis disse betingelsene er sanne, skal vi markere raden med blå bakgrunn. Formelen i Formater verdier hvor denne formelen er sann blir:

=OG(C2<>0;REST(RAD();2)<>0)

OG() gjør at vi kan sjekke flere betingelser i en jafs.

C2<>0 sjekker om cella er tom

REST(RAD();2)<>0 sjekker om vi får en rest hvis vi deler radnummeret med 2.

Så klikker vi på knappen Formater, velger Fyll og velger bakgrunnsfarge og eventuelt settinger for Skrift og Kantlinje.

Klikker du OK nå, skal regelen se omtrent slik ut:

I videoen har jeg endret området i Gjelder til =$C$2:$F$1000. Dette er å ta i – vi har ingen ingen fylker med 1000 kommuner…

Last ned

Her kan du laste ned Excelboka: Betinget formatering - Pyjamaspapir på skjermen (2 downloads )