FILTRER() Filtrere på dato, klokkeslett og hverdag

|
AvKetil Øyesvold Melhus Publisert Redigert

Jeg sitter og koser meg glugg ihjel med funksjonen FILTRER(), og imponeres stadig over hvor mange timers programmeringsjobb denne funksjonen sparer meg for.

I eksemplet har jeg i underkant av 38.000 med dato og klokkeslett i kolonne A. Oppgaven er å filtrere ut alle verdiene i kolonne B-F hvor datoen i kolonne A skal ligge innenfor et valgfritt intervall. Klokkeslettet skal være mellom 08: og 16:00, og lørdag og søndag skal ekskluderes. Fascinerende å se hvor effektivt det kan løses med funksjonen FILTRER()

Les også: FILTRER() – bare lekkert
Les også: FILTRER() igjen – nå både rader og kolonner

Lenke til excelboka som benyttes i eksemplet finner du nederst i artikkelen.

(Artikkelen fortsetter under videoruten. )
YouTube player

Formelen som benyttes

= FILTRER(A2:F100000;
      (A2:A100000 >= P2)
    * (A2:A100000 <= P3)
    * ((A2:A100000) - HELTALL(A2:A100000) >= P6)
    * ((A2:A100000) - HELTALL(A2:A100000) <= P7)
    * (UKEDAG(A2:A100000; 2) <> 6)
    * (UKEDAG(A2:A100000; 2) <> 7))

Forklaring til formelen

= FILTRER(A2:F100000; ‘Området vi skal trekke ut rader fra
(A2:A100000 >= P2) ‘Datoen skal være større eller lik verdien i P2 (Fra dato)
* (A2:A100000 <= P3) ‘Datoen skal være mindre eller lik verdien i P3 (Til dato)
* ((A2:A100000) – HELTALL(A2:A100000) >= P6) ‘Restverdien skal være større eller lik P6 (Fra klokka)
* ((A2:A100000) – HELTALL(A2:A100000) <= P7) ‘Restverdien skal være mindre eller lik P7 (Til klokka)
* (UKEDAG(A2:A100000; 2) <> 6) ‘Ukedagen skal være forskjellig fra 6
* (UKEDAG(A2:A100000; 2) <> 7)) ‘Ukedagen skal være forskjellig fra 7

Format med en eller flere betingelser

Med en betingelse er formatet slik:

= FILTRER(A2:F100000; A2:A100000 >= P2)

Når det er flere betingelser, skal hver enkelt betingelse stå i parentes med gangetegn (*) i mellom: 

= FILTRER(A2:F100000;(A2:A100000 >= P2)*(A2:A100000 <= P3))

Last ned excelboka her: Filtrer 03 - Filtrere noen tusen rader på dato, tid og hverdag (8 downloads )

Similar Posts